#include <hardware.h>
	.module	crt0
	.globl	_main

	.area	_HEADER (ABS)
	.org	0x8000
start:
	ld	a, #0x80
	ld	i, a
	ld	sp, #0x0000
main:
	call	gsinit
	call	_main
1$:
	halt
	jr	1$

;;; Interrupt table
	.org	0x8020
_ctc0_isr_ptr::
	.dw	#0
_ctc1_isr_ptr::
	.dw	#0
_ctc2_isr_ptr::
	.dw	#0
_ctc3_isr_ptr::
	.dw	#0
_port_a_isr_ptr::
	.dw	#0
_port_b_isr_ptr::
	.dw	#0
_rx_isr_ptr::
	.dw	#0

	;; Ordering of segments for the linker.
	.area	_HOME
	.area	_CODE
	.area	_INITIALIZER
	.area	_GSINIT
	.area	_GSFINAL
	.area	_DATA
	.area	_INITIALIZED
	.area	_BSEG
	.area	_BSS
	.area	_HEAP
	.area	_CODE
	.area	_GSINIT

gsinit:
	;; Default-initialized global variables.
	ld	bc, #l__DATA
	ld	a, b
	or	a, c
	jr	Z, zeroed_data
	ld	hl, #s__DATA
	ld	(hl), #0x00
	dec	bc
	ld	a, b
	or	a, c
	jr	Z, zeroed_data
	ld	e, l
	ld	d, h
	inc		de
	ldir
zeroed_data:
	;; Explicitly initialized global variables.
	ld	bc, #l__INITIALIZER
	ld	a, b
	or	a, c
	jr	Z, gsinit_next
	ld	de, #s__INITIALIZED
	ld	hl, #s__INITIALIZER
	ldir

gsinit_next:
	.area	_GSFINAL
	ret